Variable names
       Perl has three built-in data types: scalars, arrays of scalars, and
       associative arrays of scalars, known as "hashes".  A scalar is a single
       string (of any size, limited only by the available memory), number, or
       a reference to something (which will be discussed in perlref).  Normal
       arrays are ordered lists of scalars indexed by number, starting with 0.
       Hashes are unordered collections of scalar values indexed by their
       associated string key.

       Values are usually referred to by name, or through a named reference.
       The first character of the name tells you to what sort of data
       structure it refers.  The rest of the name tells you the particular
       value to which it refers.  Usually this name is a single identifier,
       that is, a string beginning with a letter or underscore, and containing
       letters, underscores, and digits.  In some cases, it may be a chain of
       identifiers, separated by "::" (or by the slightly archaic "'"); all
       but the last are interpreted as names of packages, to locate the
       namespace in which to look up the final identifier (see "Packages" in
       perlmod for details).  For a more in-depth discussion on identifiers,
       see "Identifier parsing".  It's possible to substitute for a simple
       identifier, an expression that produces a reference to the value at
       runtime.   This is described in more detail below and in perlref.

       Perl also has its own built-in variables whose names don't follow these
       rules.  They have strange names so they don't accidentally collide with
       one of your normal variables.  Strings that match parenthesized parts
       of a regular expression are saved under names containing only digits
       after the "$" (see perlop and perlre).  In addition, several special
       variables that provide windows into the inner working of Perl have
       names containing punctuation characters and control characters.  These
       are documented in perlvar.

       Scalar values are always named with '$', even when referring to a
       scalar that is part of an array or a hash.  The '$' symbol works
       semantically like the English word "the" in that it indicates a single
       value is expected.

           $days               # the simple scalar value "days"
           $days[28]           # the 29th element of array @days
           $days{'Feb'}        # the 'Feb' value from hash %days
           $#days              # the last index of array @days

       Entire arrays (and slices of arrays and hashes) are denoted by '@',
       which works much as the word "these" or "those" does in English, in
       that it indicates multiple values are expected.

           @days               # ($days[0], $days[1],... $days[n])
           @days[3,4,5]        # same as ($days[3],$days[4],$days[5])
           @days{'a','c'}      # same as ($days{'a'},$days{'c'})

       Entire hashes are denoted by '%':

       different variables.  It also means that $foo[1] is a part of @foo, not
       a part of $foo.  This may seem a bit weird, but that's okay, because it
       is weird.

       Because variable references always start with '$', '@', or '%', the
       "reserved" words aren't in fact reserved with respect to variable
       names.  They are reserved with respect to labels and filehandles,
       however, which don't have an initial special character.  You can't have
       a filehandle named "log", for instance.  Hint: you could say
       "open(LOG,'logfile')" rather than "open(log,'logfile')".  Using
       uppercase filehandles also improves readability and protects you from
       conflict with future reserved words.  Case is significant--"FOO",
       "Foo", and "foo" are all different names.  Names that start with a
       letter or underscore may also contain digits and underscores.

       It is possible to replace such an alphanumeric name with an expression
       that returns a reference to the appropriate type.  For a description of
       this, see perlref.

       Names that start with a digit may contain only more digits.  Names that
       do not start with a letter, underscore, digit or a caret (i.e.  a
       control character) are limited to one character, e.g.,  $% or $$.
       (Most of these one character names have a predefined significance to
       Perl.  For instance, $$ is the current process id.)

   Identifier parsing
       Up until Perl 5.18, the actual rules of what a valid identifier was
       were a bit fuzzy.  However, in general, anything defined here should
       work on previous versions of Perl, while the opposite -- edge cases
       that work in previous versions, but aren't defined here -- probably
       won't work on newer versions.  As an important side note, please note
       that the following only applies to bareword identifiers as found in
       Perl source code, not identifiers introduced through symbolic
       references, which have much fewer restrictions.  If working under the
       effect of the "use utf8;" pragma, the following rules apply:

           / (?[ ( \p{Word} & \p{XID_Start} ) + [_] ]) \p{XID_Continue}* /x

       If not under "use utf8", the source is treated as ASCII + 128 extra
       controls, and identifiers should match

           / (?aa) (?!\d) \w+ /x

       That is, any word character in the ASCII range, as long as the first
       character is not a digit.

       There are two package separators in Perl: A double colon ("::") and a
       single quote ("'").  Normal identifiers can start or end with a double
       colon, and can contain several parts delimited by double colons.
       Single quotes have similar rules, but with the exception that they are
       not legal at the end of an identifier: That is, "$'foo" and "$foo'bar"
       are legal, but "$foo'bar'" are not.

       Finally, if the identifier is preceded by a sigil -- More so, normal
                     |   \{ \s* (?&normal_identifier) \s* \}
                 (?: :: )* '?
                  (?: (?= (?: :: )+ '? | (?: :: )* ' ) (?&normal_identifier) )?
                 (?: :: )*
               # is use utf8 on?
                 (?(?{ (caller(0))[8] & $utf8::hint_bits })
                     (?&Perl_XIDS) \p{XID_Continue}*
                   | (?aa) (?!\d) \w+
             (?<sigil> [&*\$\@\%])
             (?<Perl_XIDS> (?[ ( \p{Word} & \p{XID_Start} ) + [_] ]) )

       Meanwhile, special identifiers don't follow the above rules; For the
       most part, all of the identifiers in this category have a special
       meaning given by Perl.  Because they have special parsing rules, these
       generally can't be fully-qualified.  They come in four forms:

       A sigil, followed solely by digits matching \p{POSIX_Digit}, like $0,
       $1, or $10000.
       A sigil, followed by either a caret and a single POSIX uppercase
       letter, like $^V or $^W, or a sigil followed by a literal control
       character matching the "\p{POSIX_Cntrl}" property. Due to a historical
       oddity, if not running under "use utf8", the 128 extra controls in the
       "[0x80-0xff]" range may also be used in length one variables.
       Similar to the above, a sigil, followed by bareword text in brackets,
       where the first character is either a caret followed by an uppercase
       letter, or a literal control, like "${^GLOBAL_PHASE}" or
       A sigil followed by a single character matching the "\p{POSIX_Punct}"
       property, like $! or "%+".

       The interpretation of operations and values in Perl sometimes depends
       on the requirements of the context around the operation or value.
       There are two major contexts: list and scalar.  Certain operations
       return list values in contexts wanting a list, and scalar values
       otherwise.  If this is true of an operation it will be mentioned in the
       documentation for that operation.  In other words, Perl overloads
       certain operations based on whether the expected return value is

           sort( <STDIN> )

       then the sort operation provides list context for <>, which will
       proceed to read every line available up to the end of file, and pass
       that list of lines back to the sort routine, which will then sort those
       lines and return them as a list to whatever the context of the sort

       Assignment is a little bit special in that it uses its left argument to
       determine the context for the right argument.  Assignment to a scalar
       evaluates the right-hand side in scalar context, while assignment to an
       array or hash evaluates the righthand side in list context.  Assignment
       to a list (or slice, which is just a list anyway) also evaluates the
       right-hand side in list context.

       When you use the "use warnings" pragma or Perl's -w command-line
       option, you may see warnings about useless uses of constants or
       functions in "void context".  Void context just means the value has
       been discarded, such as a statement containing only ""fred";" or
       "getpwuid(0);".  It still counts as scalar context for functions that
       care whether or not they're being called in list context.

       User-defined subroutines may choose to care whether they are being
       called in a void, scalar, or list context.  Most subroutines do not
       need to bother, though.  That's because both scalars and lists are
       automatically interpolated into lists.  See "wantarray" in perlfunc for
       how you would dynamically discern your function's calling context.

   Scalar values
       All data in Perl is a scalar, an array of scalars, or a hash of
       scalars.  A scalar may contain one single value in any of three
       different flavors: a number, a string, or a reference.  In general,
       conversion from one form to another is transparent.  Although a scalar
       may not directly hold multiple values, it may contain a reference to an
       array or hash which in turn contains multiple values.

       Scalars aren't necessarily one thing or another.  There's no place to
       declare a scalar variable to be of type "string", type "number", type
       "reference", or anything else.  Because of the automatic conversion of
       scalars, operations that return scalars don't need to care (and in
       fact, cannot care) whether their caller is looking for a string, a
       number, or a reference.  Perl is a contextually polymorphic language
       whose scalars can be strings, numbers, or references (which includes
       objects).  Although strings and numbers are considered pretty much the
       same thing for nearly all purposes, references are strongly-typed,
       uncastable pointers with builtin reference-counting and destructor

       A scalar value is interpreted as FALSE in the Boolean sense if it is
       undefined, the null string or the number 0 (or its string equivalent,
       "0"), and TRUE if it is anything else.  The Boolean context is just a
       special kind of scalar context where no conversion to a string or a
       number is ever performed.
       the undef() operator to produce an undefined value.

       To find out whether a given string is a valid non-zero number, it's
       sometimes enough to test it against both numeric 0 and also lexical "0"
       (although this will cause noises if warnings are on).  That's because
       strings that aren't numbers count as 0, just as they do in awk:

           if ($str == 0 && $str ne "0")  {
               warn "That doesn't look like a number";

       That method may be best because otherwise you won't treat IEEE
       notations like "NaN" or "Infinity" properly.  At other times, you might
       prefer to determine whether string data can be used numerically by
       calling the POSIX::strtod() function or by inspecting your string with
       a regular expression (as documented in perlre).

           warn "has nondigits"        if     /\D/;
           warn "not a natural number" unless /^\d+$/;             # rejects -3
           warn "not an integer"       unless /^-?\d+$/;           # rejects +3
           warn "not an integer"       unless /^[+-]?\d+$/;
           warn "not a decimal number" unless /^-?\d+\.?\d*$/;     # rejects .2
           warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/;
           warn "not a C float"
               unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/;

       The length of an array is a scalar value.  You may find the length of
       array @days by evaluating $#days, as in csh.  However, this isn't the
       length of the array; it's the subscript of the last element, which is a
       different value since there is ordinarily a 0th element.  Assigning to
       $#days actually changes the length of the array.  Shortening an array
       this way destroys intervening values.  Lengthening an array that was
       previously shortened does not recover values that were in those

       You can also gain some minuscule measure of efficiency by pre-extending
       an array that is going to get big.  You can also extend an array by
       assigning to an element that is off the end of the array.  You can
       truncate an array down to nothing by assigning the null list () to it.
       The following are equivalent:

           @whatever = ();
           $#whatever = -1;

       If you evaluate an array in scalar context, it returns the length of
       the array.  (Note that this is not true of lists, which return the last
       value, like the C comma operator, nor of built-in functions, which
       return whatever they feel like returning.)  The following is always

           scalar(@whatever) == $#whatever + 1;

       Some programmers choose to use an explicit conversion so as to leave
       nothing to doubt:
       isn't supposed to happen.  If a tied hash is evaluated in scalar
       context, the "SCALAR" method is called (with a fallback to "FIRSTKEY").

       You can preallocate space for a hash by assigning to the keys()
       function.  This rounds up the allocated buckets to the next power of

           keys(%users) = 1000;                # allocate 1024 buckets

   Scalar value constructors
       Numeric literals are specified in any of the following floating point
       or integer formats:

           .23E-10             # a very small number
           3.14_15_92          # a very important number
           4_294_967_296       # underscore for legibility
           0xff                # hex
           0xdead_beef         # more hex
           0377                # octal (only numbers, begins with 0)
           0b011011            # binary

       You are allowed to use underscores (underbars) in numeric literals
       between digits for legibility (but not multiple underscores in a row:
       "23__500" is not legal; "23_500" is).  You could, for example, group
       binary digits by threes (as for a Unix-style mode argument such as
       0b110_100_100) or by fours (to represent nibbles, as in 0b1010_0110) or
       in other groups.

       String literals are usually delimited by either single or double
       quotes.  They work much like quotes in the standard Unix shells:
       double-quoted string literals are subject to backslash and variable
       substitution; single-quoted strings are not (except for "\'" and "\\").
       The usual C-style backslash rules apply for making characters such as
       newline, tab, etc., as well as some more exotic forms.  See "Quote and
       Quote-like Operators" in perlop for a list.

       Hexadecimal, octal, or binary, representations in string literals (e.g.
       '0xff') are not automatically converted to their integer
       representation.  The hex() and oct() functions make these conversions
       for you.  See "hex" in perlfunc and "oct" in perlfunc for more details.

       You can also embed newlines directly in your strings, i.e., they can
       end on a different line than they begin.  This is nice, but if you
       forget your trailing quote, the error will not be reported until Perl
       finds another line containing the quote character, which may be much
       further on in the script.  Variable substitution inside strings is
       limited to scalar variables, arrays, and array or hash slices.  (In
       other words, names beginning with $ or @, followed by an optional
       bracketed expression as a subscript.)  The following code segment
       prints out "The price is $100."

           $Price = '$100';    # not interpolated

       must also do this when interpolating a variable into a string to
       separate the variable name from a following double-colon or an
       apostrophe, since these would be otherwise treated as a package

           $who = "Larry";
           print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n";
           print "We use ${who}speak when ${who}'s here.\n";

       Without the braces, Perl would have looked for a $whospeak, a $who::0,
       and a "$who's" variable.  The last two would be the $0 and the $s
       variables in the (presumably) non-existent package "who".

       In fact, a simple identifier within such curlies is forced to be a
       string, and likewise within a hash subscript. Neither need quoting.
       Our earlier example, $days{'Feb'} can be written as $days{Feb} and the
       quotes will be assumed automatically.  But anything more complicated in
       the subscript will be interpreted as an expression.  This means for
       example that "$version{2.0}++" is equivalent to "$version{2}++", not to

       Version Strings

       A literal of the form "v1.20.300.4000" is parsed as a string composed
       of characters with the specified ordinals.  This form, known as
       v-strings, provides an alternative, more readable way to construct
       strings, rather than use the somewhat less readable interpolation form
       "\x{1}\x{14}\x{12c}\x{fa0}".  This is useful for representing Unicode
       strings, and for comparing version "numbers" using the string
       comparison operators, "cmp", "gt", "lt" etc.  If there are two or more
       dots in the literal, the leading "v" may be omitted.

           print v9786;              # prints SMILEY, "\x{263a}"
           print v102.111.111;       # prints "foo"
           print 102.111.111;        # same

       Such literals are accepted by both "require" and "use" for doing a
       version check.  Note that using the v-strings for IPv4 addresses is not
       portable unless you also use the inet_aton()/inet_ntoa() routines of
       the Socket package.

       Note that since Perl 5.8.1 the single-number v-strings (like "v65") are
       not v-strings before the "=>" operator (which is usually used to
       separate a hash key from a hash value); instead they are interpreted as
       literal strings ('v65').  They were v-strings from Perl 5.6.0 to Perl
       5.8.0, but that caused more confusion and breakage than good.  Multi-
       number v-strings like "v65.66" and 65.66.67 continue to be v-strings

       Special Literals

       The special literals __FILE__, __LINE__, and __PACKAGE__ represent the
       current filename, line number, and package name at that point in your
       program.  __SUB__ gives a reference to the current subroutine.  They
       Text after __DATA__ may be read via the filehandle "PACKNAME::DATA",
       where "PACKNAME" is the package that was current when the __DATA__
       token was encountered.  The filehandle is left open pointing to the
       line after __DATA__.  The program should "close DATA" when it is done
       reading from it.  (Leaving it open leaks filehandles if the module is
       reloaded for any reason, so it's a safer practice to close it.)  For
       compatibility with older scripts written before __DATA__ was
       introduced, __END__ behaves like __DATA__ in the top level script (but
       not in files loaded with "require" or "do") and leaves the remaining
       contents of the file accessible via "main::DATA".

       See SelfLoader for more description of __DATA__, and an example of its
       use.  Note that you cannot read from the DATA filehandle in a BEGIN
       block: the BEGIN block is executed as soon as it is seen (during
       compilation), at which point the corresponding __DATA__ (or __END__)
       token has not yet been seen.


       A word that has no other interpretation in the grammar will be treated
       as if it were a quoted string.  These are known as "barewords".  As
       with filehandles and labels, a bareword that consists entirely of
       lowercase letters risks conflict with future reserved words, and if you
       use the "use warnings" pragma or the -w switch, Perl will warn you
       about any such words.  Perl limits barewords (like identifiers) to
       about 250 characters.  Future versions of Perl are likely to eliminate
       these arbitrary limitations.

       Some people may wish to outlaw barewords entirely.  If you say

           use strict 'subs';

       then any bareword that would NOT be interpreted as a subroutine call
       produces a compile-time error instead.  The restriction lasts to the
       end of the enclosing block.  An inner block may countermand this by
       saying "no strict 'subs'".

       Array Interpolation

       Arrays and slices are interpolated into double-quoted strings by
       joining the elements with the delimiter specified in the $" variable
       ($LIST_SEPARATOR if "use English;" is specified), space by default.
       The following are equivalent:

           $temp = join($", @ARGV);
           system "echo $temp";

           system "echo @ARGV";

       Within search patterns (which also undergo double-quotish substitution)
       there is an unfortunate ambiguity:  Is "/$foo[bar]/" to be interpreted
       as "/${foo}[bar]/" (where "[bar]" is a character class for the regular
       expression) or as "/${foo[bar]}/" (where "[bar]" is the subscript to
       array @foo)?  If @foo doesn't otherwise exist, then it's obviously a


       In a context not requiring a list value, the value of what appears to
       be a list literal is simply the value of the final element, as with the
       C comma operator.  For example,

           @foo = ('cc', '-E', $bar);

       assigns the entire list value to array @foo, but

           $foo = ('cc', '-E', $bar);

       assigns the value of variable $bar to the scalar variable $foo.  Note
       that the value of an actual array in scalar context is the length of
       the array; the following assigns the value 3 to $foo:

           @foo = ('cc', '-E', $bar);
           $foo = @foo;                # $foo gets 3

       You may have an optional comma before the closing parenthesis of a list
       literal, so that you can say:

           @foo = (

       To use a here-document to assign an array, one line per element, you
       might use an approach like this:

           @sauces = <<End_Lines =~ m/(\S.*\S)/g;
               normal tomato
               spicy tomato
               green chile
               white wine

       LISTs do automatic interpolation of sublists.  That is, when a LIST is
       evaluated, each element of the list is evaluated in list context, and
       the resulting list value is interpolated into LIST just as if each
       individual element were a member of LIST.  Thus arrays and hashes lose
       their identity in a LIST--the list


       contains all the elements of @foo followed by all the elements of @bar,
       followed by all the elements returned by the subroutine named SomeSub
       called in list context, followed by the key/value pairs of %glarch.  To
       make a list reference that does NOT interpolate, see perlref.

       The null list is represented by ().  Interpolating it in a list has no

       A list value may also be subscripted like a normal array.  You must put
       the list in parentheses to avoid ambiguity.  For example:

           # Stat returns list value.
           $time = (stat($file))[8];

           # SYNTAX ERROR HERE.
           $time = stat($file)[8];  # OOPS, FORGOT PARENTHESES

           # Find a hex digit.
           $hexdigit = ('a','b','c','d','e','f')[$digit-10];

           # A "reverse comma operator".
           return (pop(@foo),pop(@foo))[0];

       Lists may be assigned to only when each element of the list is itself
       legal to assign to:

           ($a, $b, $c) = (1, 2, 3);

           ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00);

       An exception to this is that you may assign to "undef" in a list.  This
       is useful for throwing away some of the return values of a function:

           ($dev, $ino, undef, undef, $uid, $gid) = stat($file);

       List assignment in scalar context returns the number of elements
       produced by the expression on the right side of the assignment:

           $x = (($foo,$bar) = (3,2,1));       # set $x to 3, not 2
           $x = (($foo,$bar) = f());           # set $x to f()'s return count

       This is handy when you want to do a list assignment in a Boolean
       context, because most list functions return a null list when finished,
       which when assigned produces a 0, which is interpreted as FALSE.

       It's also the source of a useful idiom for executing a function or
       performing an operation in list context and then counting the number of
       return values, by assigning to an empty list and then using that
       assignment in scalar context.  For example, this code:

           $count = () = $string =~ /\d+/g;

       will place into $count the number of digit groups found in $string.
       This happens because the pattern match is in list context (since it is
       being assigned to the empty list), and will therefore return a list of
       all matching parts of the string.  The list assignment in scalar
       context will translate that into the number of elements (here, the
       number of times the pattern matched) and assign that to $count.  Note
       that simply using

           $count = $string =~ /\d+/g;

       A hash can be initialized using a literal list holding pairs of items
       to be interpreted as a key and a value:

           # same as map assignment above
           %map = ('red',0x00f,'blue',0x0f0,'green',0xf00);

       While literal lists and named arrays are often interchangeable, that's
       not the case for hashes.  Just because you can subscript a list value
       like a normal array does not mean that you can subscript a list value
       as a hash.  Likewise, hashes included as parts of other lists
       (including parameters lists and return lists from functions) always
       flatten out into key/value pairs.  That's why it's good to use
       references sometimes.

       It is often more readable to use the "=>" operator between key/value
       pairs.  The "=>" operator is mostly just a more visually distinctive
       synonym for a comma, but it also arranges for its left-hand operand to
       be interpreted as a string if it's a bareword that would be a legal
       simple identifier.  "=>" doesn't quote compound identifiers, that
       contain double colons.  This makes it nice for initializing hashes:

           %map = (
                        red   => 0x00f,
                        blue  => 0x0f0,
                        green => 0xf00,

       or for initializing hash references to be used as records:

           $rec = {
                       witch => 'Mable the Merciless',
                       cat   => 'Fluffy the Ferocious',
                       date  => '10/31/1776',

       or for using call-by-named-parameter to complicated functions:

          $field = $query->radio_group(
                      name      => 'group_name',
                      values    => ['eenie','meenie','minie'],
                      default   => 'meenie',
                      linebreak => 'true',
                      labels    => \%labels

       Note that just because a hash is initialized in that order doesn't mean
       that it comes out in that order.  See "sort" in perlfunc for examples
       of how to arrange for an output ordering.

       If a key appears more than once in the initializer list of a hash, the
       last occurrence wins:

           %circle = (

       This can be used to provide overridable configuration defaults:

           # values in %args take priority over %config_defaults
           %config = (%config_defaults, %args);

       An array can be accessed one scalar at a time by specifying a dollar
       sign ("$"), then the name of the array (without the leading "@"), then
       the subscript inside square brackets.  For example:

           @myarray = (5, 50, 500, 5000);
           print "The Third Element is", $myarray[2], "\n";

       The array indices start with 0.  A negative subscript retrieves its
       value from the end.  In our example, $myarray[-1] would have been 5000,
       and $myarray[-2] would have been 500.

       Hash subscripts are similar, only instead of square brackets curly
       brackets are used.  For example:

           %scientists =
               "Newton" => "Isaac",
               "Einstein" => "Albert",
               "Darwin" => "Charles",
               "Feynman" => "Richard",

           print "Darwin's First Name is ", $scientists{"Darwin"}, "\n";

       You can also subscript a list to get a single element from it:

           $dir = (getpwnam("daemon"))[7];

   Multi-dimensional array emulation
       Multidimensional arrays may be emulated by subscripting a hash with a
       list.  The elements of the list are joined with the subscript separator
       (see "$;" in perlvar).


       is equivalent to

           $foo{join($;, $a, $b, $c)}

       The default subscript separator is "\034", the same as SUBSEP in awk.

       A slice accesses several elements of a list, an array, or a hash
       simultaneously using a list of subscripts.  It's more convenient than
       writing out the individual elements as a list of separate scalar
           @folks[0, -1]  = @folks[-1, 0];

       The previous assignments are exactly equivalent to

           ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/;
           ($colors{'red'}, $colors{'blue'}, $colors{'green'})
                          = (0xff0000, 0x0000ff, 0x00ff00);
           ($folks[0], $folks[-1]) = ($folks[-1], $folks[0]);

       Since changing a slice changes the original array or hash that it's
       slicing, a "foreach" construct will alter some--or even all--of the
       values of the array or hash.

           foreach (@array[ 4 .. 10 ]) { s/peter/paul/ }

           foreach (@hash{qw[key1 key2]}) {
               s/^\s+//;           # trim leading whitespace
               s/\s+$//;           # trim trailing whitespace
               s/(\w+)/\u\L$1/g;   # "titlecase" words

       A slice of an empty list is still an empty list.  Thus:

           @a = ()[1,0];           # @a has no elements
           @b = (@a)[0,1];         # @b has no elements


           @a = (1)[1,0];          # @a has two elements
           @b = (1,undef)[1,0,2];  # @b has three elements

       More generally, a slice yields the empty list if it indexes only beyond
       the end of a list:

           @a = (1)[  1,2];        # @a has no elements
           @b = (1)[0,1,2];        # @b has three elements

       This makes it easy to write loops that terminate when a null list is

           while ( ($home, $user) = (getpwent)[7,0]) {
               printf "%-8s %s\n", $user, $home;

       As noted earlier in this document, the scalar sense of list assignment
       is the number of elements on the right-hand side of the assignment.
       The null list contains no elements, so when the password file is
       exhausted, the result is 0, not 2.

       Slices in scalar context return the last item of the slice.

           @a = qw/first second third/;
           %h = (first => 'A', second => 'B');
           $t = @a[0, 1];                  # $t is now 'second'

       represents all types.  This used to be the preferred way to pass arrays
       and hashes by reference into a function, but now that we have real
       references, this is seldom needed.

       The main use of typeglobs in modern Perl is create symbol table
       aliases.  This assignment:

           *this = *that;

       makes $this an alias for $that, @this an alias for @that, %this an
       alias for %that, &this an alias for &that, etc.  Much safer is to use a
       reference.  This:

           local *Here::blue = \$There::green;

       temporarily makes $Here::blue an alias for $There::green, but doesn't
       make @Here::blue an alias for @There::green, or %Here::blue an alias
       for %There::green, etc.  See "Symbol Tables" in perlmod for more
       examples of this.  Strange though this may seem, this is the basis for
       the whole module import/export system.

       Another use for typeglobs is to pass filehandles into a function or to
       create new filehandles.  If you need to use a typeglob to save away a
       filehandle, do it this way:

           $fh = *STDOUT;

       or perhaps as a real reference, like this:

           $fh = \*STDOUT;

       See perlsub for examples of using these as indirect filehandles in

       Typeglobs are also a way to create a local filehandle using the local()
       operator.  These last until their block is exited, but may be passed
       back.  For example:

           sub newopen {
               my $path = shift;
               local  *FH;  # not my!
               open   (FH, $path)          or  return undef;
               return *FH;
           $fh = newopen('/etc/passwd');

       Now that we have the *foo{THING} notation, typeglobs aren't used as
       much for filehandle manipulations, although they're still needed to
       pass brand new file and directory handles into or out of functions.
       That's because *HANDLE{IO} only works if HANDLE has already been used
       as a handle.  In other words, *FH must be used to create new symbol
       table entries; *foo{THING} cannot.  When in doubt, use *FH.

       All functions that are capable of creating filehandles (open(),
               return $fh;

               my $f = myopen("</etc/motd");
               print <$f>;
               # $f implicitly closed here

       Note that if an initialized scalar variable is used instead the result
       is different: "my $fh='zzz'; open($fh, ...)" is equivalent to "open(
       *{'zzz'}, ...)".  "use strict 'refs'" forbids such practice.

       Another way to create anonymous filehandles is with the Symbol module
       or with the IO::Handle module and its ilk.  These modules have the
       advantage of not hiding different types of the same name during the
       local().  See the bottom of "open" in perlfunc for an example.

       See perlvar for a description of Perl's built-in variables and a
       discussion of legal variable names.  See perlref, perlsub, and "Symbol
       Tables" in perlmod for more discussion on typeglobs and the *foo{THING}

perl v5.18.2                      2014-01-06                       PERLDATA(1)
Man Pages Copyright Respective Owners. Site Copyright (C) 1994 - 2018 Hurricane Electric. All Rights Reserved.